import oscP5.*;
import netP5.*;

OscP5 osc;
int port = 6449;
String tag = "/ChucKchat/text";
PFont font;
String[] lines;
int msgSize = 48;
float[] oldy, newy, hu;

void setup()
{
  size (screen.width, screen.height);
  colorMode(HSB);
  smooth();
  font = createFont("sans_serif", 48, true);
  osc = new OscP5(this, port);
  textFont(font);
  textSize(msgSize);
  textAlign(LEFT);
  int numLines = int(height / (msgSize*1.5));
  lines = new String[numLines];
  oldy = new float[numLines];
  newy = new float[numLines];
  hu = new float[numLines];
  for (int i=0; i<lines.length; i++)
  {
    lines[i]="";
    oldy[i] = 0;
    newy[i] = 0;
    hu[i] = 0;
  }
}

void draw()
{
  background(0);
  fill(255);
  stroke(255);
  for (int i=0; i<lines.length; i++)
  {
    float y = (1.5*msgSize) + i*msgSize*1.5;
    newy[i] = (oldy[i]+y)/2;
    oldy[i] = newy[i];
    float f = map(i, 0, lines.length, 255, 100);
    fill (hu[i], 255, 255, f);
    text(lines[i], 30, newy[i]);
  }
}

void oscEvent (OscMessage msg)
{
  String ip = msg.netAddress().address();
  String ipPieces[] = split(ip, '.');
  float pnum = float(ipPieces[3]);
  String textMsg = msg.get(0).stringValue()+": "+msg.get(1).stringValue();
  for (int i=(lines.length)-1; i>0; i--)
  {
    lines[i] = lines[i-1];
    oldy[i] = oldy[i-1];
    hu[i] = hu[i-1];
  }
  lines[0] = textMsg;
  oldy[0] = 0;
  hu[0] = map(pnum, 0, 12, 0, 128);
  println(textMsg);
}